====Shape generators====

----

**__makeshp (type 1)__**

<code z80>
; a: amplitude, c: offset, hl: adr
;   / ---+                            
;--/--+  | A               
; /   |C |                          

mkshp	push hl
     	exx
     	ld   e,a
     	ld   d,0
     	sla  e
     	rl   d
     	neg
     	ld   l,0
     	ld   h,a
     	exx
     	ld   a,c
     	exx
     	add  a,h
     	ld   h,a
     	exx
     	ld   b,0
l0001	ld   (hl),a
     	exx
     	add  hl,de
     	ld   a,h
     	exx
     	inc  hl
     	djnz l0001
     	pop  hl
     	ret
</code>

----

**__makeshp (type 2)__**

<code z80>
; a: amplitude, c: offset, hl: adr
;    /\             
; - /--\ -
;  /    \           

mkshu	push hl
     	exx                      
     	ld   e,a
     	ld   d,0
     	sla  e
     	rl   d
     	sla  e
     	rl   d
     	neg
     	ld   l,0
     	ld   h,a
     	exx
     	ld   a,c
     	exx
     	add  a,h
     	ld   h,a
     	exx
     	ld   b,80h
l0002	ld   (hl),a
     	exx
     	add  hl,de
     	ld   a,h
     	exx
     	inc  hl
     	djnz l0002
     	
     	ld   b,80h
l0003	exx
     	sbc  hl,de
     	ld   a,h
     	exx
     	ld   (hl),a
     	inc  hl
     	djnz l0003
     	pop  hl
     	ret
</code>

----

**Navigation: [[general]] . [[math]] . [[graphic]] . [[sound]] . [[system]] . [[other]] . back to [[start]]**